home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d13 / iq.arc / IQBUILD.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1988-10-23  |  4.8 KB  |  101 lines
  1. 10  REM ======================================================================
  2. 20  REM ============================= IQ Builder =============================
  3. 30  REM This program presents a menu of the programs available in the      ===
  4. 40  REM IQ Builder series and allows the user to select a program by       ===
  5. 50  REM moving the cursor to the desired program and pressing ENTER.       ===
  6. 60  REM ======================================================================
  7. 70  REM $s2
  8. 80  REM  =====================================================================
  9. 90  REM  Turn off KEY display, set display width, clear the screen and set ===
  10. 100  REM KEY(10) to reload the menu program when pressed in command mode.  ===
  11. 110  REM =====================================================================
  12. 120  REM $s2
  13. 130  KEY OFF:WIDTH 80:CLS:KEY 10,"run "+CHR$(34)+"b:???0??"+CHR$(13)
  14. 140  REM $s2
  15. 150  REM =====================================================================
  16. 160  REM Display the menu of the programs available in IQ Builder.         ===
  17. 170  REM =====================================================================
  18. 180  REM $s2
  19. 190  LOCATE 1,34,0:COLOR 0,7:PRINT " IQ Builder ";
  20. 200  LOCATE 3,10:COLOR 7,0:PRINT "The following programs are available on this diskette:";
  21. 210  LOCATE 5,30:PRINT "Number Series"
  22. 220  LOCATE 6,30:PRINT "Analogies"
  23. 230  LOCATE 7,30:PRINT "Synonyms"
  24. 240  LOCATE 8,30:PRINT "Antonyms"
  25. 270  LOCATE 16,1:PRINT"Use the ";:COLOR 15:PRINT"UP ("CHR$(24)")";:COLOR 7:PRINT" and ";:COLOR 15:PRINT"DOWN ("CHR$(25)")";:COLOR 7:PRINT" arrows to position the cursor to the function"
  26. 280  LOCATE 17,1:PRINT"desired and then press the ";:COLOR 15:PRINT"ENTER ("CHR$(17)CHR$(196)CHR$(217)")";:COLOR 7:PRINT" key."
  27. 283  PRINT
  28. 284  PRINT "At any time during the programs, you may:"
  29. 285  PRINT "       Press   F9   to advance to the next program."
  30. 286  PRINT "       Press   F10  to return to this menu."
  31. 290  REM $s2
  32. 300  REM =====================================================================
  33. 310  REM Set up the initial coordinates for the selection arrow.           ===
  34. 320  REM =====================================================================
  35. 330  REM $s2
  36. 340  X=25:Y=5
  37. 350  REM $pa
  38. 360  REM =====================================================================
  39. 370  REM Set up UP and DOWN arrows for moving selection arrow.             ===
  40. 380  REM =====================================================================
  41. 390  REM $s2
  42. 400  KEY(11) ON:KEY(14) ON:ON KEY(11) GOSUB 730:ON KEY(14) GOSUB 800
  43. 410  REM $s2
  44. 420  REM =====================================================================
  45. 430  REM Set up KEY(10) to return to MENU program on A-disk.               ===
  46. 440  REM =====================================================================
  47. 450  REM $s2
  48. 460  KEY(10) ON:ON KEY(10) GOSUB 1000
  49. 470  REM $s2
  50. 480  REM =====================================================================
  51. 490  REM Display highlighted selection arrow at Y,X.                       ===
  52. 500  REM =====================================================================
  53. 510  REM $s2
  54. 520  COLOR 31:LOCATE Y,X:PRINT "==>";
  55. 530  REM $s2
  56. 540  POKE 106,0'clear kybd buffer
  57. 550  REM $s2
  58. 560  REM =====================================================================
  59. 570  REM If ENTER is pressed, go to program run routine.                   ===
  60. 580  REM =====================================================================
  61. 590  REM $s2
  62. 600  IF INKEY$ = CHR$(13) THEN BEEP:COLOR 7:CLS:GOTO 870
  63. 610  REM $s2
  64. 620  REM =====================================================================
  65. 630  REM Display the date and time at the bottom of the display.           ===
  66. 640  REM =====================================================================
  67. 650  REM $s2
  68. 660  COLOR 7:LOCATE 25,25:PRINT DATE$,TIME$;
  69. 670  GOTO 520
  70. 680  REM $pa
  71. 690  REM =====================================================================
  72. 700  REM Move the selection arrow up if it isn't at the top of the menu.   ===
  73. 710  REM =====================================================================
  74. 720  REM $s2
  75. 730  BEEP:Y1=CSRLIN:X1=POS(0):LOCATE Y,X:PRINT "   ";:LOCATE Y1,X1:IF Y>5 THEN Y=Y-1
  76. 740  RETURN 520
  77. 750  REM $s2
  78. 760  REM =====================================================================
  79. 770  REM Move the selection arrow down if it isn't at the top of the menu. ===
  80. 780  REM =====================================================================
  81. 790  REM $s2
  82. 800  BEEP:Y1=CSRLIN:X1=POS(0):LOCATE Y,X:PRINT "   ";:LOCATE Y1,X1:IF Y<8 THEN Y=Y+1
  83. 810  RETURN 520
  84. 820  REM $s2
  85. 830  REM =====================================================================
  86. 840  REM Run the selected program. If selection is invalid, return to menu.===
  87. 850  REM =====================================================================
  88. 860  REM $s2
  89. 870  IF Y=5 THEN RUN "numbers.iq"
  90. 880  IF Y=6 THEN RUN "analog.iq"
  91. 890  IF Y=7 THEN RUN "synonym.iq"
  92. 900  IF Y=8 THEN RUN "antonym.iq"
  93. 930  BEEP:LOCATE 2,1:PRINT "Please make another selection."
  94. 940  FOR I=1 TO 1000:NEXT I:RUN
  95. 950  REM $s2
  96. 960  REM =====================================================================
  97. 970  REM Return to MENU program on the A-disk.                             ===
  98. 980  REM =====================================================================
  99. 990  REM $s2
  100. 1000  COLOR 7,0:RUN "basmenu"
  101.